LTspice/SwCADⅢ・電子回路シュミレータ・デバイス追加
第一期は今から２０年近く前のＰＣ－９８０１の初期の頃にＪＲ０ＸＭＣ／ＡＣ６ＰＡ山本さんと言う古い友達にMicro-Cap（ＭＣと呼んでいた？） と言う電子回路シュミレータを覚えなさいと・・・。
第二期は１９９５年にＪＨ３ＥＲＱ藤本さんと津山のＥＭＥミーティングの時、じわーっと勉強しませんか？ＦＮＸさん！の優しい声・・・・・
第三期は２００２年頃？？ＪＡ６ＸＫＱ武安さんに進められ、やっと、フリーだったＡＮＳＯＦＴの電子回路シュミレータをある程度・・・なめました。
マニュアル通りに動かないところがあってＸＫＱさんに質問しなくてはと思っていてまたまた、そのままになりました。
そして２００４年、ＳＣ－ＰＡＮＦＩを作った頃、やっと、重たい腰を上げて本気で覚えようと努力をしました。
第四期はＡＮＳＯＦＴは難しかったので今度はLTspice/SwCADⅢを使ってみました。
これは結構簡単で５５５を使った倍倍倍電圧電源のシュミレーションも出来ました。
LTspice/SwCADⅢは良かったのですがデバイスの種類が少ない・デバイスの増やし方がわからない・・・色々あってこれもこの時は一時お休みでした。
第五期は・・・あのＯｒＣＡＤだったらデバイスもおおいかと期待し
ＣＱ出版の電子回路シミュレータPSpice入門編
http://www.cqpub.co.jp/hanbai/books/36/36271.htm
を買ってあそんでみました。
しかし、OrCAD Family Release 9.2 Lite Editionではノード数が少なくて本当に小さな回路しか出なくて自分の頭でシュミレートした方が大きい回路が出来ました。
でも、製品版は無いし買えないしウイニーにもないやろうし。。。。
悔しい思いをしました。
これを！
WinSpice Web site
http://www.winspice.com/
Spice3f5 マニュアル
日本語訳 by Ayumi’s Lab.
http://ayumi.cava.jp/audio/spiceman/spiceman.html
まじめに勉強しょうかと思いましたが覚えても回路図がああ回路図がと言う事で覚えてもそのまま実用にはならないと思いました。
LTspice/SwCADⅢはSpice3ベースらしくて何でも同じように出来る様な？事が一番最後に紹介するSpiceの大先生たちのサイトに書いてあったのです。
第六期は、もう一度本気でLTspice/SwCADⅢを覚えたということです。
僕が一番難しいと思ったデバイスの増やし方を忘れない内にまとめて、おこうと思って書きました。
何分にも素人ですので間違いが一杯あるかもしれません。
ぜひ、間違いをお教えください。
奥も縦も横も深い高い広い電子回路シュミレータですのでまだ直流から低周波のエミュレーションが出来る様になっただけですがずいぶん便利なものです。
もし、電子回路シュミレータが使えない方は是非、是非、是非、騙されたと思って使える様になってみてください。
僕みたいに歳を取ってから覚えるものではありません。
しかし、ＳＰＩＣＥ／電子回路シュミレータは本当に非常に楽しい物です。
皆さんも是非、回路を書いて動かして楽しんでください。
愛媛県八幡浜市 ＪＡ５ＦＮＸ 田村文史郎
スタート！！
標準で入っていないデバイスを追加するには？
デバイスの追加を行うには適切なＳＰＩＣＥ ＭＯＤＥＬと追加方法が重要なポイントになります。
ＳＰＩＣＥ ＭＯＤＥＬはデバイスメーカのサイトでもダウンロード出来ますが私たちが普段良く使うレガシー？なデバイスのＳＰＩＣＥ ＭＯＤＥＬはなかなか手に入らないようです。
おなじみのデバイスについては少々怪しいのもありますが（失礼！）数理設計研究所さまのSpice and Modelをつかわさせて頂きました。
ダイオード
LTCSwCADIIIlibcmpにあるstandard.dioに
—
.model 1N60 D(IS=1.6E-15 N=0.3439 RS=72.1 CJO=1PF)
.model 1ss16 D(IS=2.18E-6 N=1.07 RS=2.1 CJO=1.13pf VJ=1.336 M=0.2244 TT=0.1ns BV=6v IBV=100E-15)
.model 1ss106 D(IS=2.35E-5 N=2.524 RS=48.12 CJO=1.36pf VJ=0.294 M=0.1635 TT=.1ns BV=40 IBV=100E-15)
.model rd5a D (IS=0.5uA RS=40 BV=5.00 IBV=0.5uA)
.model rd6a D (IS=0.5uA RS=30 BV=6.00 IBV=0.5uA)
.model rd7a D (IS=0.5uA RS=12 BV=7.00 IBV=0.5uA)
.model rd9a D (IS=0.5uA RS=10 BV=9.00 IBV=0.5uA)
.model rd11a D (IS=0.5uA RS=20 BV=11.00 IBV=0.5uA)
.model rd13a D (IS=0.5uA RS=25 BV=13.00 IBV=0.5uA)
.model rd14a D (IS=0.5uA RS=27 BV=14.00 IBV=0.5uA)
.model rd16a D (IS=0.5uA RS=30 BV=16.00 IBV=0.5uA)
.model rd19a D (IS=0.5uA RS=50 BV=19.00 IBV=0.5uA)
.model rd24a D (IS=0.5uA RS=100 BV=24.00 IBV=0.5uA)
—
上記の様に．ｍｏｄｅｌを追加してやれば簡単に増やせるようです。
（上記のＳＰＩＣＥ ＭＯＤＥＬは数理設計研究所のSpice and Modelでダウンロードさせて頂いた物です。）
数理設計研究所
http://www.madlabo.com/mad/index.htm
Spice and Model
http://www.madlabo.com/mad/edat/spice/index.htm
トランジスタ
LTCSwCADIIIlibcmpにあるstandard.dioに．．．．
—
.model 2SA1015 PNP(Is=295.1E-18 Xti=3 Eg=1.11 Vaf=100 Bf=110 Ne=1.5 Ise=0 Ikf=0 Xtb=1.5 Br=10.45 Nc=2 Isc=0 Ikr=0 Rc=15 Cjc=66.2p Mjc=1.054 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=1.661n Itf=0 Vtf=0 Xtf=0 Vceo=50 Icrating=150m mfg=TOSHIBA)
.model 2SC1815 NPN(Is=2.04f Xti=3 Eg=1.11 Vaf=6 Bf=400 Ne=1.5 Ise=0 Ikf=20m Xtb=1.5 Br=3.377 Nc=2 Isc=0 Ikr=0 Rc=1 Cjc=2p Mjc=.3333 Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n Tf=311.1p Itf=0 Vtf=0 Xtf=0 Vceo=50 Icrating=150m mfg=TOSHIBA)
—
ダイオードと同じ等に．ｍｏｄｅｌを追加してやれば簡単に増やせるようです。
（上記のＳＰＩＣＥ ＭＯＤＥＬはＣＱ出版トランジスタ技術2002年5月号 特集＊初めての回路シミュレーションでダウンロードさせて頂いた物です。）
ＣＱ出版トランジスタ技術
2002年5月号 特集＊初めての回路シミュレーション
http://www.cqpub.co.jp/toragi/download/2002/TR0205A/TR0205A.LZH
Ｊ－ＦＥＴ
LTCSwCADIIIlibcmpにあるstandard.jftに．．．．
—
.model 2SK30r NJF(vto=-0.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p)
.model 2SK30o NJF(vto=-1.1v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p)
.model 2SK30y NJF(vto=-1.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p)
.model 2SK30gr NJF(vto=-2.8v beta=0.75m lambda=0 cgd=2.6p cgs=8.2p)
.model 2SK30atm NJF(beta=.768m vto=-2.70 cgd=2.6p cgs=8.2p)
.model 2SK19 NJF(vto=-2.0v beta=7.00m lambda=0 cgd=5.0p cgs=2.3p rd=10 rs=10
—
ダイオードと同じ等に．ｍｏｄｅｌを追加してやれば簡単に増やせるようです。
（上記のＳＰＩＣＥ ＭＯＤＥＬは数理設計研究所のSpice and Modelでダウンロードさせて頂いた物です。）
数理設計研究所
http://www.madlabo.com/mad/index.htm
Spice and Model
http://www.madlabo.com/mad/edat/spice/index.htm
ＭＯＳ－ＦＥＴ
下記のＳＰＩＣＥ ＭＯＤＥＬはメーカが発表しているＳＰＩＣＥ ＭＯＤＥＬです。
—
原本ＳＰＩＣＥ ＭＯＤＥＬ
—
.SUBCKT M2SJ598 1 2 3
**************************************
* Model Generated by NEC *
* All Rights Reserved *
*Commercial Use or Resale Restricted *
**************************************
* Model generated on Decenber 1, 2000
* MODEL FORMAT: SPICE2G.6
* POWER MOSFET Model (Version 3.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
***************************************
M1 4 5 3 3 PMOS W=1.1378648 L=0.6u
DDS 1 3 DDS
CGS 5 3 20.679E-11
RG 2 5 11
RD 1 4 RTEMP 3.187083E-3
FGD 1 5 VFGD 1
EVGD 7 0 1 5 1
DDG1 8 0 DD1
DDG2 8 7 DD1
EGD1 9 0 8 0 1
EGD2 10 0 7 8 1
COX 10 11 3.14766E-10
DCRR 9 11 DDG
VFGD 11 0 0
**************************************************************************
.MODEL PMOS PMOS (LEVEL = 3 TOX = 440E-10
+ XJ = 1.17E-6 LD = 0 WD = 0
+ TPG = 1 RS = 1.2E-3 RD = 75.8E-3
+ RG = 0 NSUB = 1.90E17 IS = 0
+ UO = 600 KAPPA = 0.85
+ NFS = 0.52E12 THETA = 0.30
+ ETA = 0
+ KP = 11.3E-6 PHI = 0.905
+ CGSO = 0 CGDO = 0 CGBO = 0
+ XQC = 1.0 AF = 1 CBD = 0
+ CBS = 0 CJ = 0 CJSW = 0
+ FC = 0.5 JS = 0 KF = 0
+ MJ = 0.5 MJSW = 0.33 PB = 0.8
+ RSH = 0)
*************************************************************************
.MODEL DDS D (CJO=3.19844E-10 VJ=0.802248001 M=0.466782508
+RS=0.011532665 IS=1.000E-10 TT=31.5E-9 N=1.250869271 BV=70)
*************************************************************************
.MODEL DDG D (CJO=2.1075E-10 VJ=0.43 M=0.434786482 IS=1E-32 N=50 FC=1E-8)
*************************************************************************
.MODEL DD1 D (CJO=0 N=1)
*************************************************************************
.MODEL RTEMP RES (TC1=0.164454417 TC2=0.000222052)
*************************************************************************
.ENDS M2SJ598
.SUBCKT M2SK3402 1 2 3
**************************************
* Model Generated by NEC *
* All Rights Reserved *
*Commercial Use or Resale Restricted *
**************************************
* Model generated on December 1, 2000
* MODEL FORMAT: SPICE2G.6
* POWER MOSFET Model (Version 3.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
***************************************
M1 4 5 3 3 NMOS W=4.64585 L=0.8u
DDS 3 1 DDS
CGS 5 3 4.472E-10
RG 2 5 2
RD 1 4 RTEMP 3.537E-3
FGD 1 5 VFGD 1
EVGD 7 0 1 5 1
DDG1 8 7 DD1
DDG2 8 0 DD1
EGD1 9 0 7 8 1
EGD2 10 0 8 0 1
COX 10 11 2.45675E-9
DCRR 11 9 DDG
VFGD 11 0 0
**************************************************************************
.MODEL NMOS NMOS (LEVEL = 3 TOX = 500E-10
+ XJ = 2.5E-6 LD = 0 WD = 0
+ TPG = 1 RS = 2.1E-3 RD = 4.0E-3
+ RG = 0 NSUB = 2.2E17 IS = 0
+ UO = 600 KAPPA = 2
+ NFS = 0.65E12 THETA = 0.5
+ ETA = 0
+ KP = 39E-6 PHI = 0.8
+ CGSO = 0 CGDO = 0 CGBO = 0
+ XQC = 1.0 AF = 1 CBD = 0
+ CBS = 0 CJ = 0 CJSW = 0
+ FC = 0.5 JS = 0 KF = 0
+ MJ = 0.5 MJSW = 0.33 PB = 0.8
+ RSH = 0)
*************************************************************************
.MODEL DDS D (CJO=1.22988E-9 VJ=1.351670397 M=0.561992933
+RS=0.006117249 IS=1.00E-10 TT=19E-9 N=1.099851955 BV=73)
***********************************************************************
.MODEL DDG D (CJO=1.30492E-9 VJ=0.43 M=0.533165104 IS=1E-32 N=50 FC=1E-8)
*************************************************************************
.MODEL DD1 D (CJO=0 N=1)
*************************************************************************
.MODEL RTEMP RES (TC1=0.01543 TC2=3.31817E-5)
*************************************************************************
.ENDS M2SK3402
—
をM2SK3402.LIBと言うファイル名でＬＩＢフォルダの中へ保存します。
シンボルはＮＭＯＳ．ＡＳＹをＮＭＯＳ２．ＡＳＹへコピーを行い、ＥＤＩＴ ＡｔｔｒｉｂｕｔｅｓでＰｒｅｆｉｘをＸに書き直して保存します。
回路図上のシンボルを右クリックを行いＶａｌｕｅにM2SK3402と記入します。
.lib ..SYMMYLTCLIBM2SJ598.LIB と回路図の中へＳＰＩＣＥ Ｄｉｒｅｃｔｉｖｅで指定します。
また、．ＬＩＢで指定するライブラリーには複数の.SUBCKTを入れることが出来ます。
シンボルのＶａｌｕｅに指定したデバイス名をＳＰＩＣＥ Ｄｉｒｅｃｔｉｖｅで指定したライブラリーの.SUBCKTから検索して採用されます。
トランス
ＳＰＩＣＥでのトランスの基本はＬコイルを二つ三つ・・・とＬ１・Ｌ２・Ｌ３・・・とコイルを並べて、メニューからEditでSPICE directiveのText on SchematicでK1 L1 L2 L3 1とテキストを書き回路図に置くとトランスの動作になります。
K1 L1 L2 L3 1と書くとＬ１・Ｌ２・Ｌ３が結合度１で結合していると言う事です。
巻数比はインダクタンスの比で決まります。中点タップはコイルを二つ使って作ります。
また、部品シンボルとしてと言うかライブラリとしてトランスが欲しい場合はNew Symbolでお絵かきしてNetlist Orderに合わせてSPICEモデル(SUBCKT)も作ります。
シンボルを右クリックして、さらにOpen Symbolでシンボルエディタを起動してPin/PortのNetlist Orderを確認しSUBCKT（サブサーキット？）の番号と合っていればお絵かきは何でもかまいません。
このNetlist Orderの番号がSUBCKTと呼ばれるトランスの等価回路へのインターフェースになります。
—
トランスSUBCKTの例 ファイル名 ST-1-1.INC
—
*
* ST-1-1
*
.SUBCKT ST-1-1 P B S1 S0
* Primary inductance
L1 P 1 1
* Primary DC resistance
R1 1 B 100
* Primary stray capacitance
CP P B 500P
* Secondary inductance
L2 S1 2 1
* Secondary DC resistance
R2 2 S0 100
* Secondary stray capacitance
CS S1 S0 500P
* coupling factor
K L1 L2 0.99959
.ENDS
—
LTCSwCADIIIlibの下にtransというフォルダを作成しST-1-1.INCをその中にコピーします。
シンボルを右クリックして、SpiceModelの所へST-1-1と書きます。
さらにメニューからEditでSPICE directiveのText on Schematicで .include ..transST-1-1.INC とテキストを書き回路図に置くとトランスの動作になります。
真空管
三極管、五極管のシンボルは標準で入っているようです。
しかし、ビーム管のシンボルは用意されていませんが五極管のシンボルをちょっと修正することによって簡単に作る事が出来ます。
しかし、シンボルがあっても関連するSPICEモデルがなければ何も出来ません。 真空管のSPICEモデルは
Ayumi’s Lab.
http://ayumi.cava.jp/
と言う素晴らしいサイトがあってダウンロードすることが出来ます。
このSUBCKTはべき乗がSpice3標準の^と記述されています。
LTspiceではべき乗は**なので、そのまま.includeして使う事が出来ません。
エディタで^を**に置換を行う必要があります。
沢山の本数がありますので僕は秀丸grepファイル一括置換ツールを使って一度で置きかえしました。
Replace
http://www.vector.co.jp/soft/win95/writing/se112064.html
LTCSwCADIIIlibの下にtubeというフォルダを作成し真空管名.LIBをその中にコピーします。
シンボルを右クリックして、Valueの所へ真空管名を書きます。
メニューからEditでSPICE directiveのText on Schematicで .include ..tube真空管名.LIB とテキストを書き回路図に置くと真空管の動作になります。
.subcktへパラメータを渡す。
シンボルから.lib とか.incとかの.subcktへパラメータを渡したいことがあります。
.subcktの中で{と}で挟まれた文字が変数になります。
{JA5FNX}とかくとJA5FNXが変数名になります。
この変数に値を代入する方法は色々ありますが.param a=1 b=2 JA5FNX=a+bとかの.paramで指定する方法とシンボルを右クリックして、ValueまたはValue2の値を書く所へ変数名=値 変数名=値 変数名=値 ・・・・とデータとして変数名と値を＝で繋いで何個も書いてまとめて.subcktへパラメータを渡します。
シンボルファイルの場所
ｓｙｍフォルダのとある最初の場所もしくはａｓｃファイルと同じ場所にあれば探して使用するようです。
と言うことは作ったときの場所でなくてもよいと言うこと
ライブラリの場所
回路図から見た．ＬＩＢ ．￥の．￥の場所はＬＩＢフォルダとａｓｃファイルのフォルダの二箇所を自動認識する。
回路図のフォルダは特別な取り扱いをされているようです。
追伸
LTspice/SwCADⅢ・電子回路シュミレータ・オペアンプ（ＡＤＡ４８１７）追加
https://以前のサイト/modules/weblog/details.php?blog_id=726
を書きました。
LTSpice/SwitcherCAD III
Linear – Software Downloads
http://www.linear.com/company/software.jsp
LTspiceによるシミュレーション
（初めての方用の説明書もあります）
http://homepage1.nifty.com/ntoshio/rakuen/spice/index.htm
ベルが鳴る
http://www.d1.dion.ne.jp/~river_r/bell/
電子工作な日誌
Logs of handicrafts and linux environments for embedded controllers.
http://www.koka-in.org/~kensyu/handicraft/diary.html
LTSpice/SwCADⅢを使う by Kimio kosaka
http://www.geocities.jp/ltspice_swcadiii/
Spice3f5 マニュアル
日本語訳 by Ayumi’s Lab.
http://ayumi.cava.jp/audio/spiceman/spiceman.html
WinSpice Web site
http://www.winspice.com/
数理設計研究所
http://www.madlabo.com/mad/index.htm
Spice and Model
http://www.madlabo.com/mad/edat/spice/index.htm
Ayumi’s Lab.
http://ayumi.cava.jp/
回路シミュレーターでヘッドホンアンプを作る
http://www.geocities.jp/aiwax122/orcad/orcad-1.html
夏季特別実験
http://www.px.tsukuba.ac.jp/~iarai/Doc/UG/SummerClass/syl.html
SwitcherCAD III/LTspiceのメーリングリスト等
http://groups.yahoo.com/group/LTspice/
ＣＱ出版の電子回路シミュレータPSpice入門編
http://www.cqpub.co.jp/hanbai/books/36/36271.htm
ＣＱ出版トランジスタ技術
2002年5月号 特集＊初めての回路シミュレーション
http://www.cqpub.co.jp/toragi/download/2002/TR0205A/TR0205A.LZH
